%%
%% CORE STORY PERSONA FRAGMENTS
%%
%% These fragments are used by the core story. Therefore, they can use all the story
%% context descriptors in their REQUIRES blocks, and can access the XRan palette freely.
%%
%% In addition, some of these fragments are tied to specific components, and may not
%% be readily reusable in other components.

% TYPE: *CS_PEA_DiscussTerms
%	The PC has come to negotiate a peace agreement. To do so they need to
%	get past a little bit of negotiation. There will usually be a way for
%	the PC to grease the wheels a little bit if the skill rolls don't work
%	out. This conversation snippet will lead into the NPC asking to perform
%	some task as a show of good faith.
%   PARAM1: Difficulty Rating
%   PARAM2: Success Exit Label
%   PARAM3: Give Up Exit Label

	Persona
	requires <*CS_PEA_DiscussTerms>
	% V%id%01 = Have gotten through the diplomacy
	START <if= v%id%01 0 else %2%  NewChat Say %id%01 AddChat %id%01 AddChat %id%02 AddChat %id%03 AddChat %id%04>
	.%id%_GoFailRoll <NewChat Say %id%02 AddChat %id%05 AddChat %id%06 AddChat %id%07 AddChat %id%08>
	result%id%01 <ifConversation SkillTar %1% else .%id%_GoFailRoll V= %id%01 1  AddReact d10  Goto %2%>
	result%id%02 <ifIntimidation SkillTar %1% else .%id%_GoFailRoll V= %id%01 1  AddReact d10  Goto %2%>
	result%id%03 <V= %id%01 1  Goto %2%>
	result%id%04 <V= %id%01 1  Goto %2%>
	result%id%05 <NewChat Say %id%03>
	result%id%06 <Goto %3%>
	result%id%07 <V= %id%01 1  Cash+ -100  Goto %2%>
	result%id%08 <V= %id%01 1  Goto %2%>
	Msg%id%01 <So you've come here to negotiate for peace... Why should we bother to listen to you?>
	Msg%id%02 <Is that all you can say? I'm afraid my time is too valuable to waste it on this...>
	Msg%id%03 <Think about it for as long as you need.>
	Prompt%id%01 <Peace is in all of our interests.>
	Prompt%id%02 <Because if you don't, you'll be destroyed.>
	Prompt%id%03 <This fighting hasn't been easy on your side, either.>
	CPrompt%id%03 <ifInsight SkillTar %1% Accept>
	Prompt%id%04 <You know that it's the right thing to do.>
	CPrompt%id%04 <ifG PCHeroism %1% Accept>
	Prompt%id%05 <Let me think about this for a bit.>
	Prompt%id%06 <Fine. I didn't want to negotiate peace anyhow.>
	Prompt%id%07 <I offer you $100 in tribute to your peaceful nature.>
	CPrompt%id%07 <ifG PC$ 99 ifShopping SkillTar %1% Accept>
	Prompt%id%08 <Come on, just give me a chance.>
	CPrompt%id%08 <ifG React %1% Acccept>

% TYPE: *CS_BASEPS_CaptainSurrenders
%	The captain of the ship which the PC is plundering has just surrendered.
%	Give a comment, and maybe alter the captain's attitude.
%    PARAM1: Exit Label

Persona
	requires <*CS_BASEPS_CaptainSurrenders>
	START <EndCHat Say %id%01 Goto %1%>
	Msg%id%01 <Stop, stop, we surrender! Take whatever you're looking for!>

% TYPE: *CS_BASEPS_CaptainNegotiates
%	The PC has just struck up a coversation with the captain of the ship
%	which they are currently plundering. Maybe a surrender can be forced
%	without actually doing anything.
%    PARAM1: Captain surrenders exit label
%    PARAM2: Captain attacks exit label
%    PARAM3: Nothing much happens exit label

Persona
	requires <*CS_BASEPS_CaptainNegotiates>
	START <EndCHat Say %id%01 AddCHat %id%01 AddChat %id%02>
	.%id%_GoAttack <EndChat Say %id%02 Goto %2%>
	result%id%01 <ifIntimidation HardSkillTar StoryDL else .%id%_GoAttack EndChat Say %id%03 Goto %1%>
	result%id%02 <ifStealth 3 else .%id%_GoR2Fail EndChat Say %id%04 Goto %3%>
	.%id%_GoR2Fail <EndChat Say %id%05 Goto %2%>
	Msg%id%01 <Yes, what do you want? I've got a ship to run.>
	Msg%id%02 <I thought you looked suspicious... No matter though, I won't be handing this ship over to the likes of you.>
	Msg%id%03 <Alright, I'll surrender, just calm down...>
	Msg%id%04 <Alright. Get back to work, then...>
	Msg%id%05 <Hey, you're not part of the crew... We've got an intruder on board!>
	Prompt%id%01 <Surrender now, or face my wrath!>
	Prompt%id%02 <Never mind me, just passing through...>


% TYPE: *CS_WarZone_Greeting
%	The PC has just entered a warzone. This NPC will brief the PC on what
%	happened. The PC can either sound concerned or shrug it off.
%    PARAM1: Offer help label
%    PARAM2: Noncommital label

	Persona
	requires <*CS_WarZone_Greeting>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	result%id%01 <Goto %1%>
	result%id%02 <Goto %2%>
	Msg%id%01 <The fighting appears to be over, for now... It's going to take a while to repair this damage though.>
	Msg%id%01_1 <Many lives were lost here today. Now it's time for the rest of us to repair the damage, and start preparing for the next attack...>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <The battle's over, for now. Time to start cleaning up.>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <It's going to take the rescue squad another couple of hours to count up all the casulties. Good thing this was just a minor skirmish, eh \PC ?>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Prompt%id%01 <What can I do to help?>
	Prompt%id%01_1 <Is there anything I can do?>
	Prompt%id%02 <No kidding.>
	Prompt%id%02_1 <Yeah.>



% TYPE: *CS_ForcedInduction_Greeting
%	The PC has just been shangheid into joining a faction.
%   PARAM1: Exit label (no message printed here)
%   PARAM2: Faction that's been joined

	Persona
	requires <*CS_ForcedInduction_Greeting>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	result%id%01 <AddReact d10 Goto %1%>
	result%id%02 <AddEasygoing -d10 Goto %1%>
	Msg%id%01 <You are now in the employ of \FACTION %2% ; I will expect you to act accordingly.>
	Msg%id%01_1 <Congratulations, you're one of us now. Know that as long as you're loyal to \FACTION %2% we'll be looking out for you as well.>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <You're now in the employ of \FACTION %2% . I trust you can figure out the details on your own.>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <So, you are the latest addition to the \FACTION %2% team. It's not a bad job once you get the hang of it.>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <You don't know how lucky you are to be granted membership in \FACTION %2% , \PC , but you'll learn soon enough...>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <It's so much better to join forces than to fight. I know that you'll enjoy being a member of \FACTION %2% , at least once you get used to it.>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <I hope I'm not going to regret bringing you here. It's true that \FACTION %2% needs help, but I'm not convinced that you're up to our standards.>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Prompt%id%01 <I'll do my best.>
	Prompt%id%01_1 <You can count on me.>
	Prompt%id%02 <As soon as I can find a way out, I'm gone.>
	Prompt%id%02_1 <I'll do the job, but I don't like it.>


% TYPE: *COMP_Pme_MFH_Greeting
%	The PC has just run into his friend and a bunch of hostile mecha.
%	Friend runs off, leaving PC to fight the mecha.
%   PARAM1: Exit label (no message printed here)

	Persona
	requires <*COMP_Pme_MFH_Greeting>
	START <NewChat Say %id%01 AddChat %id%01>
	result%id%01 <Goto %1%>
	Msg%id%01 <What are you doing here!?>
	Msg%id%01_1 <\PC , what in the world are you doing here!? How much do you know?>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <Why did you come here?>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <Oh, it's you. What are you doing here?>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <I can't believe it! What are you doing here?>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <Well, this is a surprise. What are you doing here?>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <Oh no... What are you doing in this place!?>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	prompt%id%01 <I could ask you the same question.>
	prompt%id%01_1 <What are YOU doing here?>
	prompt%id%01_2 <The bigger question is, why are you here?>


% TYPE: *COMP_Pun_MAE_Greeting
%	The PC is meeting his new arch-enemy for the first time. Yay!
%   PARAM1: Exit label (no message printed here)

	Persona
	requires <*COMP_Pun_MAE_Greeting E:Friend>
	start <EndChat Say %id%01 AddChat %id%01>
	result%id%01 <Goto %1%>
	Msg%id%01 <\PC ! What are you doing here? You shouldn't be in this place... you shouldn't even be in \SCENE &CompScene . I don't want to fight you but I will if I have to.>
	Prompt%id%01 <It's you who shouldn't have come here.>
	Prompt%id%01_1 <Sorry, my friend, but I won't back down either.>

	Persona
	requires <*COMP_Pun_MAE_Greeting F:++>
	start <EndChat Say %id%01 AddChat %id%01>
	result%id%01 <Goto %1%>
	Msg%id%01 <You, there! Leave this area at once or suffer the full wrath of \FACTION &EnemyFac !>
	Prompt%id%01 <I'm not afraid of \FACTION &EnemyFac .>

	Persona
	requires <*COMP_Pun_MAE_Greeting>
	start <EndChat Say %id%01 AddChat %id%01 AddChat %id%02>
	result%id%01 <Goto %1%>
	result%id%02 <EndChat Say %id%02 AddChat %id%03>
	result%id%03 <Goto %1%>
	Msg%id%01 <What do you think you're doing here? Anyone who gets in our way is going to get killed.>
	Msg%id%02 <I have no time to waste explaining things to you. The only thing you need to know is that you have no chance of defeating me.>
	Prompt%id%01 <I'm here to stop you.>
	Prompt%id%02 <Wait! I just want to know what you're doing.>
	Prompt%id%03 <I intend to prove you wrong about that.>


% TYPE: *CORE_Pme_MEIB_Greeting
%	The PC is meeting someone he's met before, but this time in battle.
%   PARAM1: Exit label (no message printed here)

	Persona
	requires <*CORE_Pme_MEIB_Greeting E:Friend>
	start <EndChat Say %id%01 AddChat %id%01>
	result%id%01 <Goto %1%>
	Msg%id%01 <What are you doing here, \PC ? I've got a job to do... if you get in my way, I won't hold back just because we're friends.>
	Prompt%id%01 <Neither will I.>
	Prompt%id%01_1 <I wouldn't expect you to.>

	Persona
	requires <*CORE_Pme_MEIB_Greeting -E:Friend>
	start <EndChat Say %id%01 AddChat %id%01>
	result%id%01 <Goto %1%>
	Msg%id%01 <Hello again \PC . We seem to keep bumping into each other... This time, though, will most probably be our last meeting.>
	Prompt%id%01 <You think you can take me? Come on.>


% TYPE: *CORE_BasicJob
%	The PC will be given a default +Tin +Ffi mission. The exact text involved
%	is going to depend upon the propp state and who the mission-giver is.
%   NOTE: This component is responsible for setting the StoryNote
%	Generally, a note will be stored for accepting the mission, but not for rejecting
%	the mission.
%   PARAM1: Accept Mission Exit Label
%   PARAM2: Reject Mission Exit Label (Note: Not all missions may be rejected!)
%	(Also note: If this component features another ending, neither exit may
%	 be called)
%   PARAM3: the location where the encounter will take place

	Persona
	requires <*CORE_BasicJob +Pew F:++>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	result%id%01 <SMemo %id%02 History %id%03 Goto %1%>
	result%id%02 <SMemo 0 Goto %2%>
	Msg%id%01 <It seems that \FACTION &EnemyFac is testing some new weapon systems in this area. Your job is to locate the research team and destroy their prototype.>
	Msg%id%01_1 <>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Msg%id%02 <\CHATNPC told you that \FACTION &EnemyFac are testing weapons nearby. You must locate and destroy their research mission in \SCENE %3% .>
	Msg%id%03 <\CHATNPC told you that \FACTION &EnemyFac were testing weapons nearby.>
	Prompt%id%01 <I'll be back when I'm done.>
	Prompt%id%01_1 <>
	Prompt%id%01_2 <>
	Prompt%id%02 <Sounds dangerous. I don't want to.>
	CPrompt%id%02 <if# PCFac ChatNPCFac Accept>
	Prompt%id%02_1 <>
	Prompt%id%02_2 <>

	Persona
	requires <*CORE_BasicJob F:-- (+Pun|+Pme)>
	% V%id%01 = Have done introduction already
	START <if= v%id%01 0 else result%id%01 NewChat Say %id%01 AddChat %id%01 AddChat %id%02 AddChat %id%03 V= %id%01 1>
	result%id%01 <NewChat Say %id%04 AddChat %id%04 AddChat %id%05>
	result%id%02 <NewChat Say %id%05 AddChat %id%04 AddChat %id%05 AddEasygoing d10>
	result%id%03 <NewChat Say %id%06 AddChat %id%04 AddChat %id%05>
	Result%id%04 <SMemo %id%02 History %id%03 Goto %1%>
	result%id%05 <SMemo 0 Goto %2%>
	Msg%id%01 <As you're probably aware, recently we've been under attack but we still don't have any good idea who's behind it.>
	Msg%id%02 <\CHATNPC sent you to intercept some mysterious attackers in \SCENE %3% .>
	Msg%id%03 <\CHATNPC sent you to intercept the mysterious attackers.>
	Msg%id%04 <There's a lance of mecha in \SCENE %3% which may be affiliated with the attackers. I want you to intercept them, and try to learn who they work for.>
	Msg%id%05 <Just a minute; if you leave now you won't be able to do this mission. There's a lance of mecha in \SCENE %3% which may be affiliated with the attackers. I want you to intercept them, and try to learn what they're after.>
	Msg%id%06 <That may well be. There's a lance of mecha in \SCENE %3% which may have been sent by the attackers. I want you to intercept them, and see if you can verify the connection with \PERSONA &EnemyNPC .>
	Prompt%id%01 <I know.>
	Prompt%id%02 <Yeah, that's why I plan to get out of here!>
	Prompt%id%03 <I'll bet \PERSONA &EnemyNPC has something to do with it.>
	CPrompt%id%03 <ifNPCOK &EnemyNPC Accept>
	Prompt%id%04 <I'll get right on it.>
	Prompt%id%05 <Sorry, but I want nothing to do with this.>
	CPrompt%id%05 <if# PCFac ChatNPCFac Accept>

	Persona
	requires <*CORE_BasicJob R:A.jr_ ArchAlly>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	Result%id%01 <StoryNote %id%02 Goto %1%>
	result%id%02 <SMemo 0 Goto %2%>
	Msg%id%01_10 <I want you to bring \PERSONA &PartnerNPC to \SCENE %3% and investigate some mecha that we've been tracking. It may turn out to be nothing, but at least it'll provide some field experience for you both.>
	CMsg%id%01_10 <ifNPCOK &PartnerNPC Accept>
	Msg%id%01_20 <We've been tracking a lance of mecha in \SCENE %3% . I need you to go there and engage them.>
	CMsg%id%01_20 <ifNPCDead &PartnerNPC Accept>
	Msg%id%02_10 <\CHATNPC sent you and \PERSONA &PartnerNPC to fight some mecha in \SCENE %3% .>
	CMsg%id%02_10 <ifNPCOK &PartnerNPC Accept>
	Msg%id%02_20 <\CHATNPC sent you to fight some mecha in \SCENE %3% .>
	CMsg%id%02_20 <ifNPCDead &PartnerNPC Accept>
	Prompt%id%01 <I'll get over there right away.>
	Prompt%id%02 <Wait, I don't think \PERSONA &PartnerNPC is ready.>
	CPrompt%id%02 <if# PCFac ChatNPCFac ifNPCOK &PartnerNPC Accept>

	Persona
	requires <*CORE_BasicJob F:++ E:++ "MILIT">
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	Result%id%01 <StoryNote %id%02 Goto %1%>
	result%id%02 <SMemo 0 Goto %2%>
	Msg%id%01 <Our intelligence reports indicate that \FACTION &EnemyFac have sent \PERSONA &EnemyNPC here on a mission. I need you to locate \OPR &EnemyNPC and make sure this mission doesn't succeed.>
	Msg%id%02 <\CHATNPC sent you to fight \PERSONA &EnemyNPC in \SCENE %3% .>
	Prompt%id%01 <Don't worry; \SPR &EnemyNPC won't get away.>
	Prompt%id%02 <I'm actually avoiding \PERSONA &EnemyNPC right now.>
	CPrompt%id%02 <if# PCFac ChatNPCFac Accept>

	Persona
	requires <*CORE_BasicJob (CORPO|TRADE) +Pun ~F:-- Common>
	START <NewChat Say %id%01 AddChat %id%01>
	Result%id%01 <StoryNote %id%02 Goto %1%>
	msg%id%01 <Our company has been under attack by mecha raiders, but we don't know who's been sending them. These attackers may be hiding in \SCENE %3% . I need you to locate them, and hopefully find some evidence to show who they're working for.>
	msg%id%02 <\CHATNPC sent you to fight mecha in \SCENE %3% , and maybe learn who they work for.>
	Prompt%id%01 <I'll get right on it.>

	Persona
	requires <*CORE_BasicJob ("CORPO"|"TRADE"|"LABOR") ~"ArchAlly" (+P--|+Pme|+Pun) Common>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	Result%id%01 <SMemo %id%02 StoryNote %id%03 Goto %1%>
	result%id%02 <SMemo 0 Goto %2%>
	msg%id%01 <Recently some of our investments have been attacked by mecha. We've been tracking one of the groups responsible to \SCENE %3% . I need you to engage them, and if possible find out who they're working for.>
	msg%id%01_1 <You may have heard that one of our factories was recently attacked by mecha. The criminals responsible are most likely hiding somewhere in \SCENE %3% ; what I need you to do is go there, locate them, and if possible find out who they're working for.>
	Cmsg%id%01_1 <ifNPCSociable Accept>
	msg%id%01_2 <A group of raiders that attacked our building has been traced to \SCENE %3% . Your task is to locate these raiders and eliminate them.>
	Cmsg%id%01_2 <ifNPCShy Accept>
	msg%id%01_3 <It's been a rough time for our company. Many of our interests have been attacked by mecha... A lance belonging to the attackers has been spotted in \SCENE %3% . I'd like for you to intercept these mecha and see if you can learn anything.>
	Cmsg%id%01_3 <ifNPCEasygoing Accept>
	msg%id%01_4 <Our company is under attack; this cannot be tolerated. A single lance of the mecha responsible has been spotted in \SCENE %3% . I need you to intercept and destroy them.>
	Cmsg%id%01_4 <ifNPCPassionate Accept>
	msg%id%01_5 <Recently some of our holdings have been attacked by mecha, but after the most recent incident we got lucky. The group responsible has been traced to \SCENE %3% . Your job is to intercept these mecha and find out who sent them.>
	Cmsg%id%01_5 <ifNPCCheerful Accept>
	msg%id%01_6 <The recent string of mecha attacks has cost our company far too much... One of the groups involved has been traced to \SCENE %3% . Your job is to intercept and eliminate them.>
	Cmsg%id%01_6 <ifNPCMelancholy Accept>
	msg%id%02 <\CHATNPC asked you to find the mecha in \SCENE %3% which have been attacking company investments.>
	msg%id%03 <You were sent to find the mecha which had been attacking company investments.>
	Prompt%id%01 <I'll get right on it.>
	Prompt%id%01_1 <Just leave it to me.>
	Prompt%id%01_2 <Don't worry, I'll find them.>
	Prompt%id%02 <I'm not interested.>
	CPrompt%id%02 <if# PCFac ChatNPCFac Accept>
	Prompt%id%02_1 <Sorry, I don't want this job.>

	Persona
	requires <*CORE_BasicJob  ("POLIT"|"MILIT") -"ARchENEMY" -L:ENEMY +Pun Common>
	START <NewChat Say %id%01 AddChat %id%01>
	result%id%01 <NewChat Say %id%02 AddChat %id%02 AddChat %id%03>
	result%id%02 <StoryNote %id%03   Goto %1%>
	result%id%03 <SMemo 0 Goto %2%>
	Msg%id%01 <You've probably heard about the unknown mecha who have attacked \NARRATIVE 7 .>
	Msg%id%01_1 <Our city is under attack by unknown mecha. Nobody knows where they came from, nor what they want. All kind of rumors have been circulating. You've heard this already, I assume.>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <I suppose you've heard about the unauthorized mecha seen within city limits.>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <It looks like our city could possible be under attack. I suppose you've already heard about the mysterious mecha which have been spotted nearby?>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <\NARRATIVE 7 must be defended! You've heard about the unauthorized mecha spotted in town, haven't you?>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <Some mysterious mecha have been spotted near town. So far they haven't caused much damage, and I don't intend to let them. Have you heard anything about them?>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <\NARRATIVE 7 is under attack. A team of commando mecha has been striking at targets within the city and then disappearing. You've heard of them, I suppose.>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Msg%id%02 <Recently unauthorized mecha have been spotted near the city limits. I need a cavalier to locate these mecha and deal with them.>
	Msg%id%02_1 <I'd like for you to locate these mecha and deal with them. The safety of our city may depend on it.>
	Msg%id%02_2 <I need you to track down these mecha and see what they're up to. This could be very important for the security of \NARRATIVE 7 .>
	Msg%id%03 <\CHATNPC hired you to defend \SCENE %3% against unknown mecha.>
	Prompt%id%01 <I have heard of them, yes.>
	Prompt%id%01_1 <I have some personal experience with them.>
	CPrompt%id%01_1 <ifPCSociable Accept>
	Prompt%id%01_2 <Yes.>
	CPrompt%id%01_2 <ifPCShy Accept>
	Prompt%id%01_3 <I think I heard something about that.>
	CPrompt%id%01_3 <ifPCEasygoing Accept>
	Prompt%id%01_4 <Of course I have.>
	CPrompt%id%01_4 <ifPCPassionate Accept>
	Prompt%id%01_5 <Yes, I've heard that!>
	CPrompt%id%01_5 <ifPCCheerful Accept>
	Prompt%id%01_6 <I know they've killed already and will again.>
	CPrompt%id%01_6 <ifPCMelancholy Accept>
	Prompt%id%02 <I'll do it.>
	Prompt%id%03 <I'm not interested.>
	CPrompt%id%03 <if# PCFac ChatNPCFac Accept>


	Persona
	requires <*CORE_BasicJob>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02>
	result%id%01 <StoryNote %id%02 Goto %1%>
	result%id%02 <SMemo 0 Goto %2%>
	Msg%id%01 <We've been tracking a group of mecha in \SCENE %3% . I need you to locate them and determine whether or not they're hostile.>
	Msg%id%01_1 <There's been a group of unknown mecha operating just outside the city. I want you to identify them, and if they prove hostile engage in combat.>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <A group of possibly hostile mecha has been detected in \SCENE %3% . I need you to intercept them.>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <There have been some odd sensor readings from \SCENE %3% , possibly indicating a group of unauthorized mecha. I need you to explore the area and see if you can find what's going on.>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <A team of unauthorized mecha has been getting too close to our holdings in \SCENE %3% . What I need you to do is locate them and put a stop to it.>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <There are some mecha in \SCENE %3% that I need investigated. Intercept them for me and you'll earn a big reward.>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <A group of unauthorized mecha has been spotted in \SCENE %3% ... these may be the same pilots responsible for those attacks earlier. I need for you to run an intercept mission.>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Msg%id%02 <\CHATNPC hired you to investigate mecha in \SCENE %3% .>
	Prompt%id%01 <I'll get to work right away.>
	Prompt%id%01_1 <Alright. I'm on the case.>
	Prompt%id%01_2 <I'll be back when I have something to report.>
	Prompt%id%02 <I'm not interested.>
	CPrompt%id%02 <if# PCFac ChatNPCFac Accept>
	Prompt%id%02_1 <Sorry, but I don't want this job.>
	Prompt%id%02_2 <Find someone else for this mission.>

	Persona
	requires <*CORE_BasicJob +P-- ~"ArchALLY" P:++ ~P:MILIT Common>
	START <NewChat Say %id%01 AddChat %id%01 AddChat %id%02 AddChat %id%04>
	result%id%01 <StoryNote %id%04 Goto %1%>
	result%id%02 <NewChat Say %id%02 AddChat %id%03 AddChat %id%04>
	result%id%03 <StoryNote %id%04 Goto %1%>
	result%id%04 <NewChat Say %id%03 randommecha .%id%_mek StoryDL  StoryNote %id%04 Goto GoR1Exit>
	.%id%_mek <GENERAL>
	Msg%id%01 <Our sensors have picked up a group of unknown mecha operating just outside the city. I need you to search \SCENE %3% and, if they prove hostile, eliminate them.>
	Msg%id%01_1 <You may have heard rumors that a group of unknown mecha were spotted near the city. Well, those aren't just rumors... I need for you to search \SCENE %3% and see if you can find them. Should they prove to be hostile, it's up to you to stop them.>
	CMsg%id%01_1 <ifNPCSociable Accept>
	Msg%id%01_2 <Sensors have picked up a signal from just outside the city. It could be mecha. I need you to go investigate.>
	CMsg%id%01_2 <ifNPCShy Accept>
	Msg%id%01_3 <There's something outside the city, possibly a group of mecha. It will be your job to go out there and find out for sure.>
	CMsg%id%01_3 <ifNPCEasygoing Accept>
	Msg%id%01_4 <Some unauthorized mecha were spotted in \SCENE %3% . They're probably enemy scouts... I need you to locate them, and if they're hostile destroy them.>
	CMsg%id%01_4 <ifNPCPassionate Accept>
	Msg%id%01_5 <Our long range sensors have detected something outside the city. It's probably nothing, but on the off chance that it's an enemy scouting party I need you to go to \SCENE %3% and investigate.>
	CMsg%id%01_5 <ifNPCCheerful Accept>
	Msg%id%01_6 <Unauthorized mecha have been detected in \SCENE %3% ... I don't have to tell you how bad the consequences would be if they are enemy forces. Your task is to locate these mecha and, if they are hostile, to eliminate them.>
	CMsg%id%01_6 <ifNPCMelancholy Accept>
	Msg%id%02 <We don't know. Until you investigate the situation, we have no way of telling.>
	Msg%id%02_10 <We won't know exactly until you investigate, but I'm sure you're capable of handling whatever it is.>
	CMsg%id%02_10 <ifG StoryDL PCRenown Accept>
	Msg%id%02_20 <We won't know until somebody investigates in person. I'm not entirely sure you're ready for a mission of this type, but it's a great chance for you to prove yourself to \NARRATIVE 3 .>
	CMsg%id%02_20 <ifG PCRenown StoryDL Accept>
	Msg%id%03 <That won't do at all. Here, take this mecha. It's a bit worn but should serve your purposes.>
	Msg%id%04 <\CHATNPC sent you to investigate unidentified mecha in \SCENE %3% .>
	Prompt%id%01 <I'll get to work right away.>
	Prompt%id%01_1 <I'm on the job.>
	Prompt%id%01_2 <Alright, I'll get striaght to work.>
	Prompt%id%02 <What am I facing out there?>
	Prompt%id%02_1 <What do you think they want?>
	Prompt%id%03 <I see...>
	Prompt%id%04 <Sorry, but I don't have a mecha right now.>
	CPrompt%id%04 <if= PCMeks 0 Accept>


